Developer/tysdk-intergration
7
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

video plugins

Browse Source
This commit is contained in:
JSD\13999
2026-03-24 11:43:22 +08:00
parent 3f78e8464a
commit 1db5db6a77
117 changed files with 28171 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

191
sdk-intergration/LocalPackages/LeviathanVideo/Runtime/Shader/YUV420P_Alpha_Right.shader Normal file
View File

@@ -0,0 +1,191 @@
Shader "LeviathanVideo/YUV420P_Alpha_Right"
{
Properties
{
[PerRendererData] _MainTex ("YTexture", 2D) = "white" {}
_UTex("UTexture",2D)="white"{}
_VTex("VTexture",2D)="white"{}
[Toggle]_ReverseY("Reverse Y",Float)=1
_Color ("Tint", Color) = (1,1,1,1)
_StencilComp ("Stencil Comparison", Float) = 8
_Stencil ("Stencil ID", Float) = 0
_StencilOp ("Stencil Operation", Float) = 0
_StencilWriteMask ("Stencil Write Mask", Float) = 255
_StencilReadMask ("Stencil Read Mask", Float) = 255
_ColorMask ("Color Mask", Float) = 15
_ValidWidthRatio ("ValidWidthRatio", Float) = 1
[Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
}
SubShader
{
Tags
{
"Queue"="Transparent"
"IgnoreProjector"="True"
"RenderType"="Transparent"
"PreviewType"="Plane"
"CanUseSpriteAtlas"="True"
}
Stencil
{
Ref [_Stencil]
Comp [_StencilComp]
Pass [_StencilOp]
ReadMask [_StencilReadMask]
WriteMask [_StencilWriteMask]
}
Cull Off
Lighting Off
ZWrite Off
ZTest [unity_GUIZTestMode]
Blend SrcAlpha OneMinusSrcAlpha
ColorMask [_ColorMask]
Pass
{
Name "Default"
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma target 2.0
#include "UnityCG.cginc"
#include "UnityUI.cginc"
#pragma multi_compile_local _ UNITY_UI_CLIP_RECT
#pragma multi_compile_local _ UNITY_UI_ALPHACLIP
#if UNITY_VERSION < 202100
inline half3 UIGammaToLinear(half3 value)
{
return value * (value * (value * 0.305306011h + 0.682171111h) + 0.012522878h);
}
#endif
//Rec.709
static const half3x3 YUV_TO_RGB = half3x3(
1.16438, 1.16438, 1.16438,
0.0, -0.21325, 2.11240,
1.79274, -0.53291, 0.0
);
static const float FLOAT_16_255 = 16.0 / 255.0;
static const float FLOAT_128_255 = 128.0 / 255.0;
struct appdata_t
{
float4 vertex : POSITION;
float4 color : COLOR;
float2 texcoord : TEXCOORD0;
UNITY_VERTEX_INPUT_INSTANCE_ID
};
struct v2f
{
float4 vertex : SV_POSITION;
fixed4 color : COLOR;
float2 texcoord : TEXCOORD0;
float4 worldPosition : TEXCOORD1;
float4 mask : TEXCOORD2;
UNITY_VERTEX_OUTPUT_STEREO
};
sampler2D _MainTex,_UTex,_VTex;
fixed4 _Color;
fixed4 _TextureSampleAdd;
float4 _ClipRect;
float4 _MainTex_ST;
float _UIMaskSoftnessX;
float _UIMaskSoftnessY;
float _ValidWidthRatio;
int _UIVertexColorAlwaysGammaSpace;
half _ReverseY;
v2f vert(appdata_t v)
{
v2f OUT;
UNITY_SETUP_INSTANCE_ID(v);
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
float4 vPosition = UnityObjectToClipPos(v.vertex);
OUT.worldPosition = v.vertex;
OUT.vertex = vPosition;
float2 pixelSize = vPosition.w;
pixelSize /= float2(1, 1) * abs(mul((float2x2)UNITY_MATRIX_P, _ScreenParams.xy));
float4 clampedRect = clamp(_ClipRect, -2e10, 2e10);
float2 maskUV = (v.vertex.xy - clampedRect.xy) / (clampedRect.zw - clampedRect.xy);
OUT.texcoord = TRANSFORM_TEX(v.texcoord.xy, _MainTex);
if (_ReverseY>0)
{
OUT.texcoord.y=1- OUT.texcoord.y;
}
OUT.mask = float4(v.vertex.xy * 2 - clampedRect.xy - clampedRect.zw, 0.25 / (0.25 * half2(_UIMaskSoftnessX, _UIMaskSoftnessY) + abs(pixelSize.xy)));
if (_UIVertexColorAlwaysGammaSpace)
{
if(!IsGammaSpace())
{
v.color.rgb = UIGammaToLinear(v.color.rgb);
}
}
OUT.color = v.color * _Color;
return OUT;
}
fixed4 frag(v2f IN) : SV_Target
{
//Round up the alpha color coming from the interpolator (to 1.0/256.0 steps)
//The incoming alpha could have numerical instability, which makes it very sensible to
//HDR color transparency blend, when it blends with the world's texture.
const half alphaPrecision = half(0xff);
const half invAlphaPrecision = half(1.0 / alphaPrecision);
IN.color.a = round(IN.color.a * alphaPrecision) * invAlphaPrecision;
half3 c = 0;
half2 uv=IN.texcoord;
half ratio = 0.5 * _ValidWidthRatio;
half2 uv1=half2(uv.x*ratio,uv.y);
half2 uv2=half2(uv.x*ratio+ratio,uv.y);
c.r = tex2D(_MainTex, uv1).a - FLOAT_16_255;
c.g = tex2D(_UTex,uv1).a - FLOAT_128_255;
c.b = tex2D(_VTex, uv1).a - FLOAT_128_255;
c=mul(c,YUV_TO_RGB);
half3 ca=0;
ca.r = tex2D(_MainTex, uv2).a - FLOAT_16_255;
ca.g = tex2D(_UTex, uv2).a - FLOAT_128_255;
ca.b = 1;
ca=mul(ca,YUV_TO_RGB);
c/=clamp(ca.b,0.01,1);
c=saturate(c);
half4 color = half4(c,ca.b);
#ifdef UNITY_COLORSPACE_GAMMA
#else
color.rgb = pow(color.rgb, 2.2);
#endif
color.rgb = color.rgb*_Color.rgb;
#ifdef UNITY_UI_CLIP_RECT
half2 m = saturate((_ClipRect.zw - _ClipRect.xy - abs(IN.mask.xy)) * IN.mask.zw);
color.a *= m.x * m.y;
#endif
#ifdef UNITY_UI_ALPHACLIP
clip (color.a - 0.001);
#endif
return color * IN.color;
}
ENDCG
}
}
}